add autoconfiguration for large (>2GB) file support

oggz_off_t (as used in oggz_read.c and oggz_seek.c) is now automatically
generated; this will need to be defined statically in config.h for
win32/ and symbian/


git-svn-id: http://svn.annodex.net/liboggz/trunk@2106 8158c8cd-e7e1-0310-9fa4-c5954c97daef

configure.ac

@@ -163,6 +163,101 @@ if test "x${ac_enable_read}" = xno && test "x${ac_enable_write}" = xno ; then
 ])
 fi
 
+dnl Large file support
+dnl Adapted from: libsndfile by Erik de Castro Lopo
+dnl
+dnl Find an appropriate type for oggz_off_t
+dnl On systems supporting files larger than 2 Gig, oggz_off_t must be a
+dnl 64 bit value. Unfortunately there is more than one way of ensuring
+dnl this so need to do some pretty rigourous testing here.
+
+unset ac_cv_sizeof_off_t
+
+AC_CHECK_SIZEOF(off_t, 1)
+
+case "$host_os" in
+    mingw*)
+        TYPEOF_OGGZ_OFF_T="__int64"
+        OGGZ_OFF_MAX="0x7FFFFFFFFFFFFFFFLL"
+        SIZEOF_OGGZ_OFF_T=8
+        ;;
+    *)
+        if test "x$ac_cv_sizeof_off_t" = "x8" ; then
+            # If sizeof (off_t) is 8, no further checking is needed.
+            TYPEOF_OGGZ_OFF_T="off_t"
+            OGGZ_OFF_MAX="0x7FFFFFFFFFFFFFFFLL"
+            SIZEOF_OGGZ_OFF_T=8
+        else
+            # Check for common 64 bit file offset types.
+            AC_CHECK_SIZEOF(loff_t,1)       # Fake default value.
+            AC_CHECK_SIZEOF(off64_t,1)      # Fake default value.
+
+            TYPEOF_OGGZ_OFF_T="unknown"
+            if test "x$ac_cv_sizeof_loff_t" = "x8" ; then
+                TYPEOF_OGGZ_OFF_T="loff_t"
+                SIZEOF_OGGZ_OFF_T=8
+            elif test "x$ac_cv_sizeof_off64_t" = "x8" ; then
+                TYPEOF_OGGZ_OFF_T="off64_t"
+                SIZEOF_OGGZ_OFF_T=8
+            fi
+
+            # Save the old sizeof (off_t) value  and then unset it to see if it
+            # changes when Large File Support is enabled.
+
+            pre_largefile_sizeof_off_t=$ac_cv_sizeof_off_t
+            unset ac_cv_sizeof_off_t
+
+            AC_SYS_EXTRA_LARGEFILE
+
+            if test "x$ac_cv_sys_largefile_CFLAGS" = "xno" ; then
+                ac_cv_sys_largefile_CFLAGS=""
+            fi
+            if test "x$ac_cv_sys_largefile_LDFLAGS" = "xno" ; then
+                ac_cv_sys_largefile_LDFLAGS=""
+            fi
+            if test "x$ac_cv_sys_largefile_LIBS" = "xno" ; then
+                ac_cv_sys_largefile_LIBS=""
+            fi
+
+            AC_CHECK_SIZEOF(off_t,1)        # Fake default value.
+
+            if test "x$ac_cv_sizeof_off_t" = "x8" ; then
+                    OGGZ_OFF_MAX="0x7FFFFFFFFFFFFFFFLL"
+            elif test "x$ac_cv_sizeof_off_t" = "x$pre_largefile_sizeof_off_t" ; then
+                AC_MSG_WARN([[This machine does not seem to support 64 bit file offsets.]])
+                TYPEOF_OGGZ_OFF_T="off_t"
+                SIZEOF_OGGZ_OFF_T=$ac_cv_sizeof_off_t
+            elif test "x$TYPEOF_OGGZ_OFF_T" = "xunknown" ; then
+                echo
+                echo "*** The configure process has determined that this system is capable"
+                echo "*** of Large File Support but has not been able to find a type which"
+                echo "*** is an unambiguous 64 bit file offset."
+                echo "*** Please contact the author to help resolve this problem."
+                echo
+                AC_MSG_ERROR([[Bad file offset type.]])
+            fi
+        fi
+    ;;
+    esac
+
+if test $SIZEOF_OGGZ_OFF_T = 4 ; then
+    OGGZ_OFF_MAX="0x7FFFFFFF"
+fi
+
+AC_DEFINE_UNQUOTED([TYPEOF_OGGZ_OFF_T],${TYPEOF_OGGZ_OFF_T}, [Set to long if unknown.])
+AC_SUBST(TYPEOF_OGGZ_OFF_T)
+
+AC_DEFINE_UNQUOTED([SIZEOF_OGGZ_OFF_T],${SIZEOF_OGGZ_OFF_T}, [Set to sizeof (long) if unknown.])
+AC_SUBST(SIZEOF_OGGZ_OFF_T)
+
+AC_DEFINE_UNQUOTED([OGGZ_OFF_MAX],${OGGZ_OFF_MAX}, [Set to maximum allowed value of sf_count_t type.])
+AC_SUBST(OGGZ_OFF_MAX)
+
+AC_CHECK_TYPES(ssize_t)
+AC_CHECK_SIZEOF(ssize_t,4)
+
+AC_DEFINE_UNQUOTED([oggz_off_t], ${TYPEOF_OGGZ_OFF_T}, [Configured type of oggz_off_t])
+
 
 dnl
 dnl Detect Ogg

m4/ac-sys-extra-largefile.m4

+dnl By default, many hosts won't let programs access large files;
+dnl one must use special compiler options to get large-file access to work.
+dnl For more details about this brain damage please see:
+dnl http://www.sas.com/standards/large.file/x_open.20Mar96.html
+
+dnl Written by Paul Eggert <eggert@twinsun.com>.
+
+dnl Internal subroutine of AC_SYS_EXTRA_LARGEFILE.
+dnl AC_SYS_EXTRA_LARGEFILE_FLAGS(FLAGSNAME)
+AC_DEFUN([AC_SYS_EXTRA_LARGEFILE_FLAGS],
+  [AC_CACHE_CHECK([for $1 value to request large file support],
+     ac_cv_sys_largefile_$1,
+     [ac_cv_sys_largefile_$1=`($GETCONF LFS_$1) 2>/dev/null` || {
+	ac_cv_sys_largefile_$1=no
+	ifelse($1, CFLAGS,
+	  [case "$host_os" in
+	   # IRIX 6.2 and later require cc -n32.
+changequote(, )dnl
+	   irix6.[2-9]* | irix6.1[0-9]* | irix[7-9].* | irix[1-9][0-9]*)
+changequote([, ])dnl
+	     if test "$GCC" != yes; then
+	       ac_cv_sys_largefile_CFLAGS=-n32
+	     fi
+	     ac_save_CC="$CC"
+	     CC="$CC $ac_cv_sys_largefile_CFLAGS"
+	     AC_TRY_LINK(, , , ac_cv_sys_largefile_CFLAGS=no)
+	     CC="$ac_save_CC"
+	   esac])
+      }])])
+
+dnl Internal subroutine of AC_SYS_EXTRA_LARGEFILE.
+dnl AC_SYS_EXTRA_LARGEFILE_SPACE_APPEND(VAR, VAL)
+AC_DEFUN([AC_SYS_EXTRA_LARGEFILE_SPACE_APPEND],
+  [case $2 in
+   no) ;;
+   ?*)
+     case "[$]$1" in
+     '') $1=$2 ;;
+     *) $1=[$]$1' '$2 ;;
+     esac ;;
+   esac])
+
+dnl Internal subroutine of AC_SYS_EXTRA_LARGEFILE.
+dnl AC_SYS_EXTRA_LARGEFILE_MACRO_VALUE(C-MACRO, CACHE-VAR, COMMENT, CODE-TO-SET-DEFAULT)
+AC_DEFUN([AC_SYS_EXTRA_LARGEFILE_MACRO_VALUE],
+  [AC_CACHE_CHECK([for $1], $2,
+     [$2=no
+changequote(, )dnl
+      $4
+      for ac_flag in $ac_cv_sys_largefile_CFLAGS no; do
+	case "$ac_flag" in
+	-D$1)
+	  $2=1 ;;
+	-D$1=*)
+	  $2=`expr " $ac_flag" : '[^=]*=\(.*\)'` ;;
+	esac
+      done
+changequote([, ])dnl
+      ])
+   if test "[$]$2" != no; then
+     AC_DEFINE_UNQUOTED([$1], [$]$2, [$3])
+   fi])
+
+AC_DEFUN([AC_SYS_EXTRA_LARGEFILE],
+  [AC_REQUIRE([AC_CANONICAL_HOST])
+   AC_ARG_ENABLE(largefile,
+     [  --disable-largefile     omit support for large files])
+   if test "$enable_largefile" != no; then
+     AC_CHECK_TOOL(GETCONF, getconf)
+     AC_SYS_EXTRA_LARGEFILE_FLAGS(CFLAGS)
+     AC_SYS_EXTRA_LARGEFILE_FLAGS(LDFLAGS)
+     AC_SYS_EXTRA_LARGEFILE_FLAGS(LIBS)
+
+     for ac_flag in $ac_cv_sys_largefile_CFLAGS no; do
+       case "$ac_flag" in
+       no) ;;
+       -D_FILE_OFFSET_BITS=*) ;;
+       -D_LARGEFILE_SOURCE | -D_LARGEFILE_SOURCE=*) ;;
+       -D_LARGE_FILES | -D_LARGE_FILES=*) ;;
+       -D?* | -I?*)
+	 AC_SYS_EXTRA_LARGEFILE_SPACE_APPEND(CPPFLAGS, "$ac_flag") ;;
+       *)
+	 AC_SYS_EXTRA_LARGEFILE_SPACE_APPEND(CFLAGS, "$ac_flag") ;;
+       esac
+     done
+     AC_SYS_EXTRA_LARGEFILE_SPACE_APPEND(LDFLAGS, "$ac_cv_sys_largefile_LDFLAGS")
+     AC_SYS_EXTRA_LARGEFILE_SPACE_APPEND(LIBS, "$ac_cv_sys_largefile_LIBS")
+     AC_SYS_EXTRA_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS,
+       ac_cv_sys_file_offset_bits,
+       [Number of bits in a file offset, on hosts where this is settable.])
+       [case "$host_os" in
+	# HP-UX 10.20 and later
+	hpux10.[2-9][0-9]* | hpux1[1-9]* | hpux[2-9][0-9]*)
+	  ac_cv_sys_file_offset_bits=64 ;;
+	esac]
+     AC_SYS_EXTRA_LARGEFILE_MACRO_VALUE(_LARGEFILE_SOURCE,
+       ac_cv_sys_largefile_source,
+       [Define to make fseeko etc. visible, on some hosts.],
+       [case "$host_os" in
+	# HP-UX 10.20 and later
+	hpux10.[2-9][0-9]* | hpux1[1-9]* | hpux[2-9][0-9]*)
+	  ac_cv_sys_largefile_source=1 ;;
+	esac])
+     AC_SYS_EXTRA_LARGEFILE_MACRO_VALUE(_LARGE_FILES,
+       ac_cv_sys_large_files,
+       [Define for large files, on AIX-style hosts.],
+       [case "$host_os" in
+	# AIX 4.2 and later
+	aix4.[2-9]* | aix4.1[0-9]* | aix[5-9].* | aix[1-9][0-9]*)
+	  ac_cv_sys_large_files=1 ;;
+	esac])
+   fi
+  ])
+

src/liboggz/oggz_read.c

@@ -67,8 +67,6 @@
 
 #define OGGZ_READ_EMPTY (-404)
 
-#define oggz_off_t long
-
 OGGZ *
 oggz_read_init (OGGZ * oggz)
 {

src/liboggz/oggz_seek.c

@@ -65,8 +65,6 @@
 
 #define CHUNKSIZE 4096
 
-#define oggz_off_t off_t
-
 /*
  * The typical usage is:
  *